1 REM COLONY 2:BY WESLEY M.ALLISON:FUBRUARY 1985
2 POKE53280,10:POKE53281,6:PRINT"[147]"
3 PRINT"          *******************":PRINT"          *                 *"
4 PRINT"          *    COLONY 2     *":PRINT"          *       BY        *"
5 PRINT"          *WESLEY M. ALLISON*":PRINT"          *                 *"
6 PRINT"          *******************"
7 PX=1
8 FORT=1TO4750:NEXTT
11 PRINT"[147]COLONY 2 IS A GAME IN WHICH YOU PLAY    THE RULER OF AN ";
12 PRINT"ISLAND COLONY."
13 PRINT"IF YOU SPEND YOUR TAX MONEY WISELY,     YOUR COLONY WILL PROSPER."
14 PRINT"YOU MUST CONSTANTLY BE AWARE OF THE     DANGERS OF PLAGUE, FAMINE, OR WAR."
15 PRINT:PRINT"YOU BEGIN WITH ONE THOUSAND CITIZENS."
16 PRINT:PRINT:PRINT"          PRESS ANY KEY"
17 GETA$:IFA$=""THEN17
18 PP=1000:TX=10000:UN=0:YR=1
19 AG=500:RN=500:FS=500:HS=500:SC=500:HP=500:FT=500:TR=500:DF=500
20 S1=0:S2=0:S3=0:S4=0:S5=0:S6=0:S7=0:S8=0:S9=0
21 PRINT"[147]"
22 PRINT"DECADE"YR
23 PRINT"POPULATION"PP
24 PRINT"UNEMPLOYED"UN
25 PRINT"TAXES \";TX
26 PRINT"HOW MUCH TAX MONEY DO YOU WISH TO SPEND ON..."
27 INPUT"AGRICULTURE";S1:IFS1>TXTHEN27
28 S1=INT(S1)
29 TX=TX-S1:PRINT"TAXES REMAINING=":PRINT"\";TX
30 INPUT"RANCHING";S2
31 S2=INT(S2)
32 TX=TX-S2:PRINT"TAXES REMAINING=":PRINT"\";TX
33 INPUT"FISHING";S3:IFS3>TXTHEN33
34 S3=INT(S3)
35 TX=TX-S3:PRINT"TAXES REMAINING=":PRINT"\";TX
36 INPUT"HOUSING";S4:IFS4>TXTHEN36
37 S4=INT(S4)
38 TX=TX-S4:PRINT"TAXES REMAINING=":PRINT"\";TX
39 INPUT"SCHOOLS";S5:IFS5>TXTHEN39
40 S5=INT(S5)
41 TX=TX-S5:PRINT"TAXES REMAINING=":PRINT"\";TX
42 INPUT"HOSPITALS";S6:IFS6>TXTHEN42
43 S6=INT(S6)
44 TX=TX-S6:PRINT"TAXES REMAINING=":PRINT"\";TX
45 INPUT"FACTORIES";S7:IFS7>TXTHEN45
46 S7=INT(S7)
47 TX=TX-S7:PRINT"TAXES REMAINING=":PRINT"\";TX
48 INPUT"TRANSPORTATION";S8:IFS8>TXTHEN48
49 S8=INT(S8)
50 TX=TX-S8:PRINT"TAXES REMAINING=":PRINT"\";TX
51 INPUT"DEFENCE";S9:IFS9>TXTHEN51
52 S9=INT(S9)
53 TX=TX-S9:PRINT"\";TX
54 PRINT"CARRIED OVER TO NEXT YEAR."
55 PRINT"           HIT A KEY"
56 GETA$:IFA$=""THEN56
57 PRINT"[147]"
58 AG=INT((AG+S1)*.9)
59 RN=INT((RN+S2)*.9)
60 FS=INT((FS+S3)*.9)
61 HS=INT((HS+S4)*.9)
62 SC=INT((SC+S5)*.8)
63 HP=INT((HP+S6)*.95)
64 FT=INT((FT+S7)*.7)
65 TR=INT(TR+S8)
66 DF=INT((DF+S9)*.8)
67 ZA=INT(1+100*RND(0))
68 IFZA>10THEN70
69 PRINT"YOUR CROPS HAVE BEEN DESTROYED          BY BLIGHT!":AG=0
70 ZB=INT(1+100*RND(0))
71 IFZB>10THEN73
72 PRINT"YOUR CATTLE HAVE BEEN KILLED BY         DISEASE!":RN=0
73 ZC=INT(1+100*RND(0))
74 IFZC>10THEN76
75 PRINT"YOUR FISHING FLEET HAS BEEN DESTROYED   BY A TYPHOON":FS=0
76 PRINT"           HIT A KEY"
77 GETA$:IFA$=""THEN77
78 PRINT"[147]        STATUS"
79 P1=INT(AG/PP*100)
80 P2=INT(RN/PP*100)
81 P3=INT(FS/PP*100)
82 P4=INT(HS/PP*100)
83 P5=INT(SC/PP*100)
84 P6=INT(HP/PP*100)
85 P7=INT(FT/PP*100)
86 P8=INT(TR/PP*100)
87 P9=INT(DF/PP*100)
88 PRINT"AGRO="P1"%"
89 PRINT"RNCH="P2"%"
90 PRINT"FISH="P3"%"
91 PRINT"HOUS="P4"%"
92 PRINT"SCHL="P5"%"
93 PRINT"HOSP="P6"%"
94 PRINT"FACT="P7"%"
95 PRINT"TRAN="P8"%"
96 PRINT"DFNC="P9"%"
97 PRINT"           HIT A KEY"
98 GETA$:IFA$=""THEN98
99 PRINT"[147]"
100 ZD=INT(1+100*RND(0))
101 IFZD>10THEN106
102 PRINT"THERE IS A PLAGUE!"
103 ZF=PP-HP:IFZF<0THENZF=0
104 PRINTZF"PEOPLE DIE."
105 PP=PP-ZF
106 ZE=INT(1+100*RND(0))
107 IFZE>10THEN113
108 PRINT"THERE IS AN INVASION!"
109 IFDF<PPTHEN112
110 PRINT"THE INVADERS ARE DEFEATED!"
111 GOTO113
112 PRINT"YOUR COLONY IS DESTROYED                YOU ARE KILLED.":GOTO130
113 PRINT"           HIT A KEY"
114 GETA$:IFA$=""THEN114
115 IA=(AG+RN+FS+HS)/4
116 IB=INT(IA-PP*1.1)
117 PP=PP+IB:IFPP<=0THEN126
118 ID=(SC+FT+TR)/3
119 IE=INT(PP-ID)
120 IFIE<0THENIE=0
121 UN=IE:IFPP>PXTHENPX=PP
122 IG=(PP-UN)*3
123 TX=TX+IG
124 YR=YR+1
125 GOTO20
126 PRINT"[147]YOUR PEOPLE ARE GONE YOU HAVE FAILED.":GOTO130
130 PRINT"           GAME OVER"
131 PRINT"      SCORE="YR*PX
132 PRINT"HIT RESTORE TO REBOOT GEOS":END